SeleniumBasic ChromeDriverClass　Chromeブラウザを扱う基本クラス

Private Sub Use_ChromeDriver()
    Dim driver As New ChromeDriver
    driver.Get "https://www.google.co.jp"
    Dim ele As selenium.WebElement
    Set ele = driver.ActiveElement
    ele.SendKeys "hoge"
    'driver.ActiveElement.SendKeys "hoge"
    driver.Wait 2000
    driver.Quit
End Sub

Private Sub FindElement_By()
    Dim driver As New ChromeDriver, elm As WebElement
    driver.Get "https://ja.wikipedia.org/wiki/メインページ"
    Set elm = driver.FindElementBy(selenium.Strategy_Css, "#about > a:nth-child(3)")
    elm.Click
    driver.Wait 2000
    driver.Quit
End Sub

Private Sub FindElement_Class()
    Dim driver As New ChromeDriver
    driver.Get "https://www.google.co.jp"
    driver.FindElementByClass("MV3Tnb").Click
    driver.Wait 2000
    driver.GoBack
    driver.Wait 2000
    driver.GoForward
    driver.Refresh
    Stop
    driver.Quit
End Sub

Private Sub AddAurgument()
    Dim driver As New ChromeDriver
'    driver.AddArgument "--headless"
    driver.AddArgument "--incognito"
    driver.AddArgument "--start-maximized"
    driver.Get "https://www.google.co.jp"
    driver.FindElementByClass("MV3Tnb").Click
    Stop
    driver.Quit
End Sub

Private Sub WaitNot_Class()
    Dim driver As New ChromeDriver
    Dim By As New By
    driver.Get "https://www.google.co.jp"
    driver.WaitNotElement By.Class("MV3Tnb"), 10000
    driver.FindElementByClass("MV3Tnb").Click
    driver.Wait 2000
    driver.Quit
End Sub

Private Sub IsElementPresent_Class()
    Dim driver As New selenium.WebDriver
    Dim By As New By
    driver.Start "chrome"
    driver.Get "https://www.google.co.jp"
    Debug.Print driver.IsElementPresent(By.Class("MV3Tnb"))
    driver.Wait 2000
    driver.Quit
End Sub

Private Sub ClipBoard_Class()
    Dim driver As New ChromeDriver
    Dim Keys As New Keys
    driver.Get "https://www.google.co.jp"
    driver.SetClipBoard "testtext"
    Debug.Print driver.GetClipBoard
    driver.FindElementByName("q").SendKeys Keys.Control, "v"
    driver.Wait 2000
    driver.Quit
End Sub

Public Sub Set_SetBinary()
    Dim driver As New WebDriver
    driver.SetBinary "C:\Program Files\Google\Chrome\Application\chrome.exe"
    driver.Start "chrome"
    driver.Window.Maximize
    driver.Wait 2000
    driver.Quit
End Sub

Private Sub Window_SwitchByTitle()
    Dim Assert As New selenium.Assert
    Dim driver As New ChromeDriver
    driver.Get "https://the-internet.herokuapp.com/windows"
    driver.FindElementByLinkText("Click Here").Click
    driver.Wait 2000
    driver.SwitchToWindowByTitle "New Window"
    Assert.Equals "New Window", driver.title
    driver.SwitchToPreviousWindow
    Assert.NotEquals "New Window", driver.title
    driver.Wait 2000
    Debug.Print driver.Windows.Count
    driver.Quit
End Sub

Private Sub Window_SwitchByName()
    Dim Keys As New Keys
    Dim driver As New ChromeDriver
    driver.Get "https://www.google.co.jp"
    Dim hwnds As selenium.List
    Set hwnds = driver.Send("GET", "/window_handles")
    driver.FindElementByClass("MV3Tnb").Click Keys.Control
    driver.SwitchToNextWindow
    driver.Wait 2000
    driver.SwitchToWindowByName hwnds.Item(1)
    driver.Wait 2000
    driver.Quit
End Sub

Private Sub Use_WaitForScript()
    Dim driver As New ChromeDriver
    driver.Get "https://ja.wikipedia.org/wiki/Main_Page"
    Dim title As String
    title = driver.ExecuteScript("return document.title;")
    driver.WaitForScript "return document.title;"
    Debug.Assert "Wikipedia" = title
    Stop
    driver.Quit
End Sub

Private Sub Use_Keboard()
    Dim driver As New ChromeDriver
    Dim Keys As New Keys
    driver.Get "https://ja.wikipedia.org/wiki/Main_Page"
    driver.Keyboard.KeyDown Keys.Control
    driver.SendKeys "a"
    driver.Keyboard.KeyUp Keys.Control
    Stop
    driver.Quit
End Sub

Private Sub Get_Title()
    Dim driver As New ChromeDriver
    Dim Keys As New Keys
    driver.Get "https://ja.wikipedia.org/wiki/Main_Page"
    Debug.Print driver.title
    driver.Quit
End Sub

Private Sub ChromeDriver_Property()
    Dim driver As New ChromeDriver
    driver.Get "https://programan.org/"
    Dim elm As selenium.WebElement
    
    driver.Window.Maximize
    Set elm = driver.FindElementByCss("#archives-2 > div")
    driver.TouchActions.FlickFrom(elm, 0, 400, 400).Wait(1500).Perform
    
    Set elm = driver.FindElementByCss("#categories-2 > ul > li.cat-item.cat-item-5 > a")
    driver.Mouse.MoveTo elm
    driver.Wait 1500
    driver.TouchScreen.Tap elm
    driver.Wait 1500
    
    Debug.Print driver.Url
    driver.Quit
End Sub

Private Sub DriverProxy_SetAutodetect()
    Const ProxyUrl As String = "192.168.11.139:3128"
    Dim driver As New ChromeDriver
    driver.Proxy.SetAutodetect
    driver.Get "https://google.co.jp"
    driver.Wait 1500
    driver.Quit
End Sub