VBA　特殊フォルダの指定方法

Private Sub 特殊フォルダ_Shell事前バインディング()
   'VBEの参照設定で、事前に「Microsoft Shell Controls And Automation」を選択
    Dim shell As New Shell32.shell, Fld As Shell32.Folder2
    Dim shellStr As String: shellStr = "shell:Local AppData"
    Set Fld = shell.Namespace(shellStr)
    Debug.Print Fld.Self.Path
End Sub

Private Sub 特殊フォルダ_Shell実行時バインディング()
    'https://learn.microsoft.com/ja-jp/windows/win32/shell/shell-namespace
    Dim shellPath As String
    Dim shellStr: shellStr = "shell:Local AppData"  'Variant型、String型を指定するとエラー発生
    shellPath = CreateObject("Shell.Application").Namespace(shellStr).Self.Path
    Debug.Print shellPath
End Sub

Private Sub 特殊フォルダ_ShellIndex一覧取得()
   'VBEの参照設定で、事前に「Microsoft Shell Controls And Automation」を選択
    Dim shell As New Shell32.shell
    Dim i As Integer
On Error GoTo ErrHandle
    For i = 0 To 61
        Debug.Print i & " " & shell.Namespace(i).Self.Path
ErrResume:
    Next i
    Exit Sub
ErrHandle:
Resume ErrResume
End Sub

Private Sub 特殊フォルダ_WSH事前バインディング()
    'VBEの参照設定で、事前に「Windows Script Host Object Model」を選択
    Dim wsh As New IWshRuntimeLibrary.WshShell
    Debug.Print wsh.SpecialFolders("DeskTop")
End Sub

Private Sub 特殊フォルダ_WSH実行時バインディング()
    Dim wsh As Object: Set wsh = CreateObject("WScript.Shell")
    Debug.Print wsh.SpecialFolders("DeskTop")
End Sub

Private Sub 特殊フォルダ_WSH_All()
    'VBEの参照設定で、事前に「Windows Script Host Object Model」を選択
    Dim wsh As New IWshRuntimeLibrary.WshShell
    Dim FldPath As String
    Dim i As Integer
    For i = 0 To wsh.SpecialFolders.Count - 1
        Debug.Print i & " " & wsh.SpecialFolders(i)
    Next i
End Sub

Private Sub 特殊フォルダ_Environ_Simple()
    Dim shellStr As String
    shellStr = Environ("USERPROFILE")
    Debug.Print shellStr
End Sub

Private Sub 特殊フォルダ_Environ_All()
    Dim envStr As String, i As Integer
    With Sheet3
    i = 1
    Do Until Environ(i) = ""
        Debug.Print i & " " & Environ(i)
        i = i + 1
    Loop
    End With
End Sub

Private Sub 特殊フォルダ_FSO事前バインディング()
    'VBEの参照設定で、事前に「Microsoft Scripting Runtime」を選択
    Dim fso As New FileSystemObject
    Debug.Print fso.GetSpecialFolder(SystemFolder)
    Debug.Print fso.GetSpecialFolder(TemporaryFolder)
    Debug.Print fso.GetSpecialFolder(WindowsFolder)
End Sub

Private Sub 特殊フォルダ_FSO実行時バインディング()
    Dim fso As Object: Set fso = CreateObject("Scripting.FileSystemObject")
    Debug.Print fso.GetSpecialFolder(0)
    Debug.Print fso.GetSpecialFolder(1)
    Debug.Print fso.GetSpecialFolder(2)
End Sub